//rish
level 1

slib = $inp(#str,'RI Library Name To Display')
::ril; = slib
pstart = $inp(#point,'Start Point')
rispace = $inp(#real,'Spacing Between RI\'s')
irow = $inp(#int,'Number Per Horizontal Row')


iold = $getvar(#txcur)            /* remember current text file number
ifile = $getvar(#txnfil)          /* get next highest text file number
$txfl(ifile)                      /* initialize (zero) the new file
$txol('wrk:rish.txt')             /* load rish.txt. By convention, the 
                                  /* file must be in the current user
                                  /* or $txol will cause a fatal error.

/* notice the two methods used to set flags here.  One uses the actual
/* flag name, the other calls an ARRIS command which sets the flag. 

$setflg(#ftxsz,.1)                /* set text size flag
$setflg(#ftxjst,'l')              /* set text justification flag
::rip;1;0;0                       /* set repeated item parameters

prio = pstart                     /* save the start point
imult = 0                         /* set the row counter to zero
$txposa(0)                        /* move text pointer to start of file

loopwhile #true                   /* a do-it-forever loop statement
	loop i = 1 while i <= irow        /* loop for the current row
		sname = $inpt(#strn)      /* get the name from the file
 		call namechk              /* a sub-routine call 
		::rin;=sname              /* set the ri name
		$setflg(#fcol,1)          /* set color to 1
		::rio;=prio;::            /* place an ri
		ptext = prio + R(0,-5,0)  /* calculate text point
		$setflg(#fcol,2)          /* set color to 2
 		::stx;=ptext;=sname;::    /* place text
		prio = prio + R(rispace,0,0)  /* calculate next ri point
                    
/* the following if check tests to see if we have gone past the end
/* of the text file.  If so, it is time to quit the program.

	if $getvar(#txpos) >= $getvar(#txend) 
		goto done
	endif

	end i++ loop
	imult++
 	prio = pstart + R(0,rispace * imult,0)
endloop

done:              /* goto label
$txfl(iold)        /* reset the text system to the previous file
:txkl;=ifile       /* get rid of the file we used
:da
!'We Be Done'
exit               /* we're done

namechk::          /* see if there's a dot in the name
	ipos = sname .pos. '.' 
	if ipos > 0
		sname = sname .left. (ipos -1)
	endif
return